blob: 44d0fb0279a66a8b4dfb662a6d048235cbf3359e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Contributor: Lex Black <autumn-wind@web.de>
pkgname=opencloud
pkgver=2.1.0
pkgrel=1
pkgdesc="secure and private way to store, access, and share your files"
url="https://github.com/opencloud-eu/opencloud"
arch=('aarch64' 'x86_64')
license=('Apache-2.0')
#depends=('glibc')
makedepends=('git' 'go' 'pnpm')
install="opencloud.install"
backup=('etc/opencloud/opencloud.env')
source=("git+https://github.com/opencloud-eu/opencloud.git#tag=v${pkgver/_/-}"
"go.mk.patch"
"opencloud.env"
"opencloud.service"
"opencloud.sysusers"
"opencloud.tmpfiles")
sha512sums=('a452cbf2f36dfc135c7ba069a23ccc9e996352eda217fe499b8b25e3c31d84550340acd5af700dd3577e0a45ba43653273094c0e40ab1dba8ec54fa435f72586'
'da70b77bf25c87d75f1a662d00a339f9b8756e6f8e33e17dcc0663d2dcd7d4981720a93fe1ba6c788d8a5e7f484f8e292e59273793106d496955c5a670862318'
'72823c7dfde7e97996f948b2371f86d37337d5f62c145b8cb9d40a4d3941cf83be96df5babbed2560cb730208e2b59fa6f363987a2c4d53f08fb2fa6870f558e'
'af6b2e80ebaf130fb3e8f6038580bea4db811499d06f2962604941f75d1f8ef0dd3692bf21e54c0611864c49217c8fa457cb6773775a1aa47c7254330f83ba7f'
'3fa38aba73ffea0e559cf20af9f12b85321a97b41d48aad5c7cea81e9ab7d35c08d7a495c62e6a9fdf6ac7c494a4926805d89171dca0d822d922902188babed3'
'e4b8c5bfda8214d6493055c996010b385c3be62a861dbcb3564c68aa03851bb6f23cd269f1b869fe4eeec6396ca9943888628c2a46215a7bd3c02c2a8f000742')
prepare() {
cd "${pkgname}"
patch .make/go.mk "${srcdir}"/go.mk.patch
}
build() {
cd ${pkgname}
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
make -j1 generate
make -C opencloud build
}
package() {
install -vDm755 "${pkgname}/${pkgname}/bin/${pkgname}" "${pkgdir}/usr/bin/${pkgname}-server"
install -vDm644 "${pkgname}.env" -t "${pkgdir}/etc/${pkgname}"
install -vDm644 "${pkgname}.service" -t "${pkgdir}/usr/lib/systemd/system"
install -vDm644 "${pkgname}.sysusers" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
install -vDm644 "${pkgname}.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
}
|