PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Contributor: Lex Black <autumn-wind@web.de>

_pkgname=opencloud-desktop
pkgname=opencloud-desktop-git
pkgver=r18046.50a6b62
pkgrel=2
pkgdesc='opencloud desktop application - git checkout'
arch=('x86_64')
url="https://github.com/opencloud-eu/desktop"
license=('GPL-2.0-only')
depends=(gcc-libs
         glibc
         kdsingleapplication
         libre-graph-api
         qt6-base
         qtkeychain-qt6
         sqlite
         zlib)
makedepends=(doxygen
             extra-cmake-modules
             git
             python-sphinx
	         qt6-declarative
             qt6-tools)
conflicts=('opencloud-desktop')
provides=('opencloud-desktop')
backup=('etc/OpenCloud/sync-exclude.lst')
source=("${_pkgname}::git+https://github.com/opencloud-eu/desktop.git")
sha256sums=('SKIP')


pkgver() {
	cd ${_pkgname}
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build() {
	cmake \
		-B build \
		-S "$_pkgname" \
		-DCMAKE_BUILD_TYPE=None \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DCMAKE_SKIP_INSTALL_RPATH=ON \
		-DBUILD_TESTING=OFF \
		-DKDE_INSTALL_SYSCONFDIR=/etc
	make -C build
}

package() {
	make DESTDIR="${pkgdir}/" -C build install
}