PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=openlibm-git
pkgver=0.8.1.r2.g1d2c5e3
pkgrel=1
pkgdesc="A high quality, portable, standalone C mathematical library"
arch=('i686' 'x86_64')
url="https://openlibm.org/"
license=('custom')
depends=('glibc')
makedepends=('git')
provides=("openlibm=$pkgver")
conflicts=('openlibm')
options=('staticlibs')
source=("git+https://github.com/JuliaMath/openlibm.git")
sha256sums=('SKIP')


prepare() {
  cd "openlibm"

  sed -e 's|/usr/local|/usr|' -i "Make.inc"
}

pkgver() {
  cd "openlibm"

  _tag=$(git tag -l --sort -v:refname | sed '/rc[0-9]*/d' | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

build() {
  cd "openlibm"

  make \
    prefix="/usr"
}

check() {
  cd "openlibm"

  make check
}

package() {
  cd "openlibm"

  make DESTDIR="$pkgdir" install
  install -Dm644 "LICENSE.md" -t "$pkgdir/usr/share/licenses/openlibm"
}