PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer:  Greg Minshall <minshall at umich dot edu>
pkgname=pacjson
pkgver=0.2.0
pkgrel=1
pkgdesc="produce a JSON representation of pacman \"-S\" and/or \"-Q\" databases"
arch=(any)
url="https://sr.ht/~minshall/pacjson/"
license=('MIT')
# pass is technically "optdepends"; but, the functionality without it
# is minimal
depends=('pyalpm' 'python>=3.0')
makedepends=('asciidoc' 'emacs' 'gawk' 'git' 'm4')
checkdepends=()
# git rev-parse in upstream repo:
# git rev-parse 0.2.0

_tag=68bd7d6e9d013470eb801535f23294c072ca77ac
source=(git+https://git.sr.ht/~minshall/pacjson#tag=${_tag}?signed)
validpgpkeys=(
    BB68C8D3A3D23B9B398FB50AC397C74C54A9EC4F # Greg Minshall <minshall@acm.org>
)
sha256sums=('SKIP')


pkgver() {
    cd "${pkgname}"
    git describe
}

build() {
    cd "${pkgname}"
    make
}

check() {
    cd "${pkgname}"

    make check
}

package() {
    cd "${pkgname}"

    make DESTDIR="${pkgdir}" PREFIX=/usr install
    # install our MIT license
    install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}