blob: e5c60e7ab36075a041462891afed9f9493a700bc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
pkgname=pantheon-music-git
pkgver=8.0.0.r16.g24912715
pkgrel=1
pkgdesc='The Pantheon Music Player'
arch=(x86_64)
url=https://github.com/elementary/music
license=(GPL-3.0-or-later)
groups=(pantheon-unstable)
depends=(
gdk-pixbuf2
glib2
glibc
gst-plugins-base-libs
gstreamer
libadwaita
libgranite-7.so
)
makedepends=(
appstream
git
gobject-introspection
granite7
intltool
meson
vala
)
optdepends=(
'gst-plugins-base: "Base" plugin libraries'
'gst-plugins-good: "Good" plugin libraries'
'gst-plugins-bad: "Bad" plugin libraries'
'gst-plugins-ugly: "Ugly" plugin libraries'
'gst-libav: Libav plugin'
)
provides=(pantheon-music)
conflicts=(pantheon-music)
source=(pantheon-music::git+https://github.com/elementary/music.git)
sha256sums=('SKIP')
pkgver() {
cd pantheon-music
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
arch-meson pantheon-music build
ninja -C build
}
package() {
DESTDIR="${pkgdir}" ninja -C build install
}
# vim: ts=2 sw=2 et:
|