PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

pkgname=paperwork-git
_pkgname=paperwork
pkgver=2.0.3+274+gb60a846c
pkgrel=1
pkgdesc="Personal document manager for GNOME to manage scanned documents and PDFs"
arch=(any)
url="https://openpaper.work/"
license=(GPL3)
depends=('gtk3'
         'libinsane'
         'libnotify'
         'poppler-glib'
         'python-cairo'
         'python-dateutil'
         'python-distro'
         'python-gobject'
         'python-levenshtein'
         'python-natsort'
         'python-numpy'
         'python-pillowfight'
         'python-pycountry'
         'python-pydbus'
         'python-pyenchant'
         'python-pyocr'
         'python-scikit-learn'
         'python-scipy'
         'python-setuptools'
         'python-simplebayes'
         'python-termcolor'
         'python-whoosh'
         'python-xdg')
makedepends=('git')
provides=('paperwork')
conflicts=('paperwork')
source=("git+https://gitlab.gnome.org/World/OpenPaperwork/paperwork.git")
b2sums=('SKIP')

pkgver() {
  cd $_pkgname
  git describe --tags | sed 's/-/+/g'
}

build() {
  cd $_pkgname
  make version
  make l10n_compile
}

package() {
  cd $_pkgname
  for dir in openpaperwork-{core,gtk} paperwork-{backend,gtk}; do
    pushd $dir
    python3 setup.py install --root="$pkgdir" --optimize=1
    popd
  done

  PYTHONPATH=`echo "$pkgdir"/usr/lib/python*/site-packages/` \
    "$pkgdir"/usr/bin/paperwork-gtk install \
      --icon_base_dir="$pkgdir/usr/share/icons" \
      --data_base_dir="$pkgdir/usr/share"
}