PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# vim:set ft=sh:
# Maintainer: Donald Webster <fryfrog@gmail.com>
# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
pkgname=par2cmdline-turbo-git
_gitname='par2cmdline-turbo'
pkgver=20230317.eaea6f4
pkgrel=1
pkgdesc="A faster PAR 2.0 compatible file verification and repair tool, forked from par2cmdline"
url="https://github.com/animetosho/par2cmdline-turbo"
license=("GPL")
makedepends=('git')
depends=('gcc-libs')
arch=('x86_64')
provides=('par2cmdline')
conflicts=('par2cmdline')
source=("$_gitname::git+https://github.com/animetosho/par2cmdline-turbo.git")
sha256sums=('SKIP')

pkgver() {
	cd "$srcdir/$_gitname"
	git log -1 --date=short --format="%cd.%h" | tr -d '-'
}

build() {
	cd ${_gitname}

	# automake
	aclocal
	automake --add-missing
	autoconf

	./configure --prefix=/usr
	make
}

check() {
	cd ${_gitname}
	make -j1 check
}

package() {
	cd ${_gitname}
	make DESTDIR=$pkgdir install
}