PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

pkgname=paraview-qt6
pkgver=5.13.1
pkgrel=1
pkgdesc="Parallel Visualization application using VTK (Qt6 version)"
arch=(x86_64)
url="https://www.paraview.org"
license=(BSD custom)
depends=(qt6-tools qt6-svg onetbb ffmpeg
         liblas python-numpy protobuf
         cgns double-conversion expat freetype2 gdal gl2ps glew hdf5 libjpeg-turbo
         jsoncpp libjsoncpp.so libharu libxml2 lz4 xz python-mpi4py netcdf
         libogg libpng pugixml libtheora libtiff zlib verdict)
optdepends=(python-matplotlib python-pandas)
makedepends=(cmake boost mesa gcc-fortran ninja)
conflicts=(paraview)
provides=(paraview)
source=(${url}/files/v${pkgver%.*}/ParaView-v${pkgver}.tar.xz)
sha256sums=('a16503ce37b999c2967d84234596e7bf67ac98221851a288bb1399c7e1dc2004')

prepare() {
  cd ParaView-v${pkgver}
  # https://gitlab.kitware.com/paraview/paraview/-/issues/22806
  patch -p1 -i ../../wl.patch
}

build() {
  cd ParaView-v${pkgver}
  cmake -G Ninja \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/opt/paraview \
    -DCMAKE_INSTALL_LICENSEDIR=share/licenses/paraview \
    -DCMAKE_CXX_STANDARD=17 \
    -DPARAVIEW_IGNORE_CMAKE_CXX11_CHECKS=ON \
    -DCMAKE_SKIP_INSTALL_RPATH=OFF \
    -DPARAVIEW_ENABLE_EMBEDDED_DOCUMENTATION=OFF \
    -DPARAVIEW_PLUGIN_DISABLE_XML_DOCUMENTATION=ON \
    -DPARAVIEW_USE_VTKM=OFF \
    -DPARAVIEW_ENABLE_XDMF3=ON \
    -DPARAVIEW_VERSIONED_INSTALL=OFF \
    -DPARAVIEW_BUILD_WITH_EXTERNAL=ON \
    -DPARAVIEW_QT_VERSION=6 \
    -DVTK_QT_VERSION=6 \
    -DVTK_SMP_IMPLEMENTATION_TYPE=TBB \
    -DVTK_MODULE_USE_EXTERNAL_VTK_cli11=OFF \
    -DVTK_MODULE_USE_EXTERNAL_VTK_eigen=OFF \
    -DVTK_MODULE_USE_EXTERNAL_VTK_exprtk=OFF \
    -DVTK_MODULE_USE_EXTERNAL_VTK_fmt=OFF \
    -DVTK_MODULE_USE_EXTERNAL_VTK_fast_float=OFF \
    -DVTK_MODULE_USE_EXTERNAL_VTK_ioss=OFF \
    -DVTK_MODULE_USE_EXTERNAL_VTK_pegtl=OFF \
    -DVTK_MODULE_USE_EXTERNAL_VTK_token=OFF \
    -DVTK_MODULE_USE_EXTERNAL_VTK_utf8=OFF \
    -B build .
  ninja -C build ${MAKEFLAGS}
}

package() {
  cd ParaView-v${pkgver}
  DESTDIR="${pkgdir}" ninja -C build install
}