PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

# Maintainer: Bart Libert <bart plus aur at libert dot email>
pkgname=pass-menu-git
pkgver=r11.b862cb0
pkgrel=1
pkgdesc="Simple Frontend for Password Store, for fzf, dmenu and similar"
arch=('any')
url="https://github.com/udayvir-singh/pass-menu"
license=('MIT')
depends=('bash' 'findutils' 'pass')
makedepends=('git' 'make')
optdepends=('libnotify: notification support'
	'oath-toolkit: generating OTP codes'
	'xclip: clipboard support on X11'
	'xdotool: autofill support on X11'
	'wl-clipboard: clipboard support on wayland'
	'wtype: autofill support on wayland'
	)
provides=("${pkgname%-git}")
source=("${pkgname%-git}::git+${url}")
sha256sums=('SKIP')

pkgver() {
	cd "$srcdir/${pkgname%-git}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
	cd "$srcdir/${pkgname%-git}"
	make PREFIX="$pkgdir/usr" install
	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}