PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer: Yoan Blanc <yoan@dosimple.ch>

pkgname='passgo'
pkgver=2.1.0
pkgrel=1
pkgdesc='Simple golang password manager.'
url='https://github.com/ejcx/passgo'
arch=('x86_64' 'i686')
license=('MIT')

depends=('glibc')
makedepends=('git' 'go')
checkdepends=('go')
source=(
  "${url}/archive/v${pkgver}.tar.gz"
)

sha256sums=(
  '6de3b0cfce92f68dc1e6090841cba822cad7673625effc50bee83ad1df75ff73'
)

build() {
  export CGO_LDFLAGS="$LDFLAGS"
  export GOFLAGS='-buildmode=pie -trimpath -modcacherw'
  _commit=$(zcat "v${pkgver}.tar.gz" | git get-tar-commit-id)
  _flags=(
    -X=main.version=v$pkgver
    -X=main.commit=${_commit::7}
    -X=main.date=$(date -u -d "@${SOURCE_DATE_EPOCH}" +'%FT%TZ')
  )
  pushd "${pkgname}-${pkgver}"
  go build -o "$pkgname" -ldflags="${_flags[*]}"
  popd
}

check() {
  pushd "${pkgname}-${pkgver}"
  go test -v ./...
  popd
}

package() {
  pushd "${pkgname}-${pkgver}"
  install -Dm755 "$pkgname" "$pkgdir"/usr/bin/"$pkgname"
  popd
}