PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Maintainer: Maxwell Pray a.k.a. Synthead <synthead@gmail.com>
# Contributor: Oliver Charles <oliver.g.charles@googlemail.com>

pkgname='perl-fcgi-procmanager'
_cpanname='FCGI-ProcManager'
pkgver='0.28'
pkgrel='1'
pkgdesc='Functions for managing FastCGI applications'
arch=('any')
license=('PerlArtistic' 'GPL')
options=('!emptydirs')
depends=('perl>=5.5.0')
url="https://metacpan.org/pod/FCGI::ProcManager"
source=("https://cpan.metacpan.org/authors/id/A/AR/ARODLAND/$_cpanname-$pkgver.tar.gz")
md5sums=('26b2000544015bf7c40a4b3caa7fbba3')


# Function to change to the working directory and set
# environment variables to override undesired options.
prepareEnvironment() {
	cd "$srcdir/$_cpanname-$pkgver"
	export \
		PERL_MM_USE_DEFAULT=1 \
		PERL_AUTOINSTALL=--skipdeps \
		PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='$pkgdir'" \
		PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
		MODULEBUILDRC=/dev/null
}

build() {
	prepareEnvironment
	/usr/bin/perl Makefile.PL
	make
}

check() {
	prepareEnvironment
	make test
}

package() {
	prepareEnvironment
	make install

	# Remove "perllocal.pod" and ".packlist".
	find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
}