blob: 67e44ca874a768d7e66d39e4a7f5c8dce4a7c4df (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Stefan Göbel <aur —at— subtype —dot— de>
# Contributor: fbabetto
pkgname='perl-text-multimarkdown'
_module='Text-MultiMarkdown'
_author='B/BR/BRIANDFOY'
pkgver='1.004'
pkgrel='1'
pkgdesc='Convert MultiMarkdown syntax to (X)HTML.'
arch=('any')
url="https://metacpan.org/dist/$_module"
license=('BSD')
depends=('perl-text-markdown' 'perl-html-parser')
makedepends=('perl-module-install')
checkdepends=('perl-test-exception' 'perl-test-pod' 'perl-test-pod-coverage' 'perl-text-diff')
source=("https://cpan.metacpan.org/authors/id/$_author/$_module-$pkgver.tar.gz")
sha256sums=('b32b3fa179de0474723b08a63189415c0809bd72b46cc9516a3694b25b2eb3e4')
build() {
(
unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
export PERL_MM_USE_DEFAULT='1' PERL_AUTOINSTALL='--skipdeps'
cd "$_module-$pkgver"
perl Makefile.PL INSTALLDIRS='vendor'
make
)
}
check() {
(
cd "$_module-$pkgver"
unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
export PERL_MM_USE_DEFAULT='1'
make test
)
}
package() {
(
cd "$_module-$pkgver"
unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
make install INSTALLDIRS='vendor' DESTDIR="$pkgdir"
install -Dm644 'LICENSE' "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
find "$pkgdir" -name .packlist -delete
find "$pkgdir" -name perllocal.pod -delete
find "$pkgdir" -type d -empty -delete
)
}
#:indentSize=3:tabSize=3:noTabs=true:mode=shellscript:maxLineLen=87:
|