PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# CPAN Name  : Text::QRCode
# Maintainer: Christian Hesse <mail@eworm.de>

pkgname=perl-text-qrcode
pkgver=0.05
pkgrel=5
pkgdesc='Text-QRCode for Perl'
arch=('i686' 'x86_64')
url='https://metacpan.org/release/Text-QRCode'
license=('PerlArtistic' 'GPL')
makedepends=('perl-module-install')
depends=('perl' 'qrencode')
options=('!emptydirs')
source=("http://search.cpan.org/CPAN/authors/id/K/KU/KURIHARA/Text-QRCode-${pkgver}.tar.gz")
sha256sums=('0d5471bed596ddcd891df271c1b7983a4e39373c984d0f1ed9cb2ec4d730a173')

build() {
	cd ${srcdir}/Text-QRCode-${pkgver}

	export PERL_AUTOINSTALL="--skipdeps" PERL_MM_USE_DEFAULT="1"

	perl Makefile.PL INSTALLDIRS="vendor"
	make
}

check() {
	cd ${srcdir}/Text-QRCode-${pkgver}

	make test
}

package() {
	cd ${srcdir}/Text-QRCode-${pkgver}

	make DESTDIR="${pkgdir}" install

	find "${pkgdir}" -name .packlist -o -name perllocal.pod -delete
}