blob: abc7cfd8075d2d927064bccd88a76c3c3c98d469 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Frederik Schwan <freswa at archlinux dot org>
# Contributor: Vlad M. <vlad@archlinux.net>
# Contributor: Attila Bukor <r1pp3rj4ck[at]w4it[dot]eu>
# Contributor: D. Can Celasun <dcelasun[at]gmail[dot]com>
# Contributor: Slava Volkov <sv99sv[at]gmail[dot]com>
pkgbase=phpstorm
pkgname=(phpstorm phpstorm-jre)
pkgver=2024.3.1.1
pkgrel=1
pkgdesc='Lightweight and Smart PHP IDE'
arch=('x86_64' 'i686')
license=('custom:jetbrains')
url='https://www.jetbrains.com/phpstorm/'
depends=('glib2' 'python')
options=('!strip')
source=("https://download.jetbrains.com/webide/PhpStorm-${pkgver%b*}.tar.gz"
jetbrains-phpstorm.desktop
LICENSE)
b2sums=('496f062c2dc5fa5b9484211ac17fcb7ea95e97e1ca98b455ec12aea16942274b82035a65d33ac60d594b1529b536950c74a982925956d8407ee52a501c90ae5f'
'ae7f5b69c057c78dac26ca571fc29c5deff0ae7c2955dd39561168a1ab0e25dfd3b0c6570a42af135588e9791c96958ffaaeea6db983f4fd8e8ec68efad413a5'
'dadaf0e67b598aa7a7a4bf8644943a7ee8ebf4412abb17cd307f5989e36caf9d0db529a0e717a9df5d9537b10c4b13e814b955ada6f0d445913c812b63804e77')
package_phpstorm() {
optdepends=('phpstorm-jre: JetBrains custom Java Runtime (Recommended)'
'java-runtime: JRE - Required if phpstorm-jre is not installed'
'gnome-keyring: save login/deployment credentials safely'
'java-openjfx: rendering Markdown files')
_buildver="$(ls | grep -Eo 'PhpStorm-[[:digit:]]+\.[[:digit:]]{2,5}\.[[:digit:]]+' | sort -r | head -1 | sed 's#PhpStorm-##')"
install -dm755 "${pkgdir}"/opt/
install -dm755 "${pkgdir}"/usr/bin/
install -dm755 "${pkgdir}"/usr/share/applications/
install -dm755 "${pkgdir}"/usr/share/pixmaps/
cp -a "${srcdir}"/PhpStorm-${_buildver:?_buildver unset}/ "${pkgdir}"/opt/${pkgbase}
rm -rf "${pkgdir}"/opt/${pkgbase}/jbr
ln -s /opt/${pkgbase}/bin/${pkgbase} "${pkgdir}"/usr/bin/${pkgbase}
install -D -m 644 "${srcdir}"/jetbrains-${pkgbase}.desktop "${pkgdir}"/usr/share/applications/
install -D -m 644 "${pkgdir}"/opt/${pkgbase}/bin/${pkgbase}.svg "${pkgdir}"/usr/share/pixmaps/${pkgbase}.svg
install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE.txt
}
package_phpstorm-jre() {
pkgdesc='JBR (JetBrains Runtime) for PhpStorm - a patched JRE'
url='https://github.com/JetBrains/JetBrainsRuntime'
_buildver="$(ls | grep -Eo 'PhpStorm-[[:digit:]]+\.[[:digit:]]{2,5}\.[[:digit:]]+' | sort -r | head -1 | sed 's#PhpStorm-##')"
install -d -m 755 "${pkgdir}"/opt/${pkgbase}
cp -a "${srcdir}"/PhpStorm-${_buildver:?_buildver unset}/jbr "${pkgdir}"/opt/${pkgbase}
}
|