blob: daa75da35f07e6c42b1ca75a0d585c9162447a9f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Jonas Hvid <mail@johv.dk>
# Contributor: Alfredo Beaumont <alfredo.beaumont@gmail.com>
pkgname='picat'
pkgver='3.8'
pkgrel=2
pkgdesc='A simple, and yet powerful, logic-based multi-paradigm programming language aimed for general-purpose applications.'
arch=('x86_64')
groups=()
depends=(glibc gcc-libs)
optdepends=('coin-or-cbc: CBC MIP support'
'cvc4: CVC4 SMT support'
'glpk: GLPK MIP support'
'gurobi: Gurobi MIP support'
'z3: Z3 SMT support')
url='http://picat-lang.org/'
license=('MPL-2.0')
_pkgver=$(echo ${pkgver} | sed 's/\.//;s/#//')
source=("http://picat-lang.org/download/${pkgname}${pkgver/\./}_src.tar.gz")
b2sums=('bd602579d43d9bec3498aa0ee8e9fc5df67a3414fecb1f022642ba8a4be6ffc5d25416549420f56b7e4f3541d54c64a0b8612d3d73b61a9fc5340ed104d50804')
prepare() {
# Inherit system-wide CFLAGS and LDFLAGS (/etc/makepkg.conf):
cd "$srcdir/Picat/emu"
sed -i 's/CFLAGS = /CFLAGS += /' Makefile.linux64
sed -i 's/LFLAGS = /&$(LDFLAGS) -Wl,-z,shstk /' Makefile.linux64
}
build() {
cd "$srcdir/Picat/emu"
make -f Makefile.linux64
}
package() {
install -m644 "$srcdir/Picat/LICENSE" -Dt "$pkgdir/usr/share/licenses/$pkgname"
install -m755 "$srcdir/Picat/emu/picat" -Dt "$pkgdir/usr/bin"
install -m644 "$srcdir/Picat/lib/"* -Dt "$pkgdir/usr/lib/$pkgname"
install -m644 "$srcdir/Picat/doc/"* -Dt "$pkgdir/usr/share/doc/$pkgname"
}
|