blob: 276445f522f284b5db5a5493c400780d28cc89bf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Davide Gerhard <rainbow@irh.it>
# Contributor: Joshua Rubin <me at jawa dot dev>
pkgname=pihpsdr-git
_pkgname=pihpsdr
pkgver=r2399.a8ff0dc
pkgrel=1
pkgdesc='SDR software for HPSDR radios like Anan and Hermes Lite 2'
arch=('x86_64' 'aarch64')
# we use this insted of g0orx because it contains
# a lot of fixes and it is currently developed
url='https://github.com/dl1ycf/pihpsdr'
license=('GPL2')
depends=('fftw' 'libpulse' 'gtk3' 'soapysdr' 'alsa-lib')
makedepends=('git')
buildflags=()
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=(
"${_pkgname}::git+https://github.com/dl1ycf/${_pkgname}"
"desktop_file.patch"
# we don't like to install the full Latex to build the manual
"https://github.com/dl1ycf/${_pkgname}/releases/download/v2.4/piHPSDR-Manual-current.pdf"
)
sha512sums=('SKIP'
'ea09a0de3fc5fcc684f06273790720ca4087127cf633511c596ed44dc8f1c35330f393a98da59e90d6834b33888b92966f25b051bcb3d0716d4e7d832de52cb4'
# probably the manual is uploaded every time he does a change
'SKIP')
pkgver() {
cd "$_pkgname"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
prepare() {
patch --directory="$_pkgname" --forward --strip=1 --input="${srcdir}/desktop_file.patch"
}
build() {
cd "$_pkgname"
export CFLAGS="${CFLAGS} -D_GNU_SOURCE"
make \
GPIO= \
MIDI=ON \
SATURN=ON \
SOAPYSDR=ON \
AUDIO=PULSE
}
package() {
cd "$_pkgname"
install -D "${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
install -D release/pihpsdr/hpsdr.png -m 0644 "${pkgdir}/usr/share/pihpsdr/hpsdr.png"
install -D release/pihpsdr/hpsdr_icon.png -m 0644 "${pkgdir}/usr/share/pihpsdr/hpsdr_icon.png"
install -m 0644 -D pihpsdr.desktop "${pkgdir}/usr/share/applications/pihpsdr.desktop"
install -m 0644 -D "${srcdir}/piHPSDR-Manual-current.pdf" "${pkgdir}/usr/share/doc/pihpsdr/manual.pdf"
}
|