PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor: Javier Steinaker <jsteinaker@gmail.com>

pkgname=pinta-gtk3-git
pkgver=r2618.6d26a525
pkgrel=1
pkgdesc="Drawing/editing program modeled after Paint.NET. It's goal is to provide a simplified alternative to GIMP for casual users"
arch=('x86_64' 'i686')
url="https://pinta-project.com"
license=('MIT')
depends=('mono' 'gtk-sharp-3' 'mono-addins' 'yelp-tools' 'intltool' dotnet-runtime-7.0)
makedepends=('git' 'dotnet-sdk' 'autoconf-archive')
provides=('pinta')
conflicts=('pinta')
options=('!makeflags')
source=(git+https://github.com/PintaProject/Pinta.git#branch=gtk3)
md5sums=('SKIP')
pkgver() {
	cd "Pinta"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
	cd "Pinta"
	sed -i '/^PINTA_BUILD_OPTS/ s/$/ -maxcpucount:1/' Makefile.am
	./autogen.sh --prefix=/usr --sysconfdir=/etc --localstatedir=/var
	make
}
package() {
	cd "Pinta"
	make DESTDIR="$pkgdir" install
	install -dm755 "$pkgdir"/usr/share/licenses/$pkgname
	install -m644 license-*.txt readme.md "$pkgdir"/usr/share/licenses/$pkgname/
}