blob: 7ef6c2abdf79638d1f217eb199e5185615148478 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: TheCyberArcher <thecyberarcher@protonmail.ch>
# Contributor: Sian1468 <sian1468-aur@.39011468.xyz>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Ner0 <darkelfdarkelf666@yahoo.co.uk>
# Contributor: dcelasun <dcelasun@gmail.com>
_pkgname=plank
pkgname=${_pkgname}-git
pkgver=0.11.89.r1973.396b871
pkgrel=1
pkgdesc='Elegant, simple, clean dock'
arch=('x86_64')
url='https://launchpad.net/plank'
license=('GPL-3.0-only')
depends=('atk' 'bamf' 'cairo' 'gdk-pixbuf2' 'glib2' 'glibc' 'gnome-menus'
'gtk3' 'libgee' 'libwnck3' 'libx11' 'libxfixes' 'libxi' 'pango')
makedepends=('gnome-common' 'git' 'intltool' 'vala')
provides=('plank')
conflicts=('plank')
source=('git+https://github.com/ricotz/plank.git')
sha256sums=('SKIP')
pkgver() {
cd "${_pkgname}"
printf "%s.r%s.%s" "$(git describe --tags --abbrev=0 | sed 's/^v//')" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd plank
sed 's/0.19.6/0.20/' -i configure.ac
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd plank
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--disable-apport
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
make DESTDIR="${pkgdir}" -C plank install
}
# vim: ts=2 sw=2 et:
|