blob: 7eeb4c288ddc2cd6f6504ae31c8b27d53602c09a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: swweetp <swweetp@outlook.com>
# Contributor: Amirul Fitri <tounghacker@gmail.com>
pkgname=playit
pkgver=0.15.26
pkgrel=1
pkgdesc="A tunneling tool to host a game server without port forwarding or sharing public IP"
arch=('x86_64')
url="https://playit.gg"
depends=('glibc' 'gcc-libs')
license=('BSD-2-Clause')
makedepends=('cargo')
source=(
"${pkgname}-${pkgver}.tar.gz::https://github.com/playit-cloud/playit-agent/archive/refs/tags/v${pkgver}.tar.gz"
"systemd-service.patch"
"tmpfiles.conf"
)
sha256sums=('3aad55efbd8371ae7bc49cc8a9a27ea975e96aa93046c959f9bce84676af9bb4'
'27e70d8498049ab785e04076e4e0b8fea7ddb9639ad3bbef93241cc96adb6ad8'
'91c4f8c54d07f5877de216263e586ac96a6cf33e29219f1436e8447adb62cf9d')
options=(!lto)
prepare() {
cd "playit-agent-${pkgver}"
patch -Np1 -i ../systemd-service.patch
#cargo update # FIXME: remove later when upstream update Cargo.lock
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "${CARCH}-unknown-linux-gnu"
}
build() {
cd "playit-agent-${pkgver}"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
}
check() {
cd "playit-agent-${pkgver}"
export RUSTUP_TOOLCHAIN=stable
# cargo test --frozen --all-features # FIXME: build failed, when enable check! :(
}
package() {
cd "playit-agent-${pkgver}"
install -Dm755 target/release/playit-cli "${pkgdir}"/usr/bin/"${pkgname}"
install -Dm644 linux/playit.service "${pkgdir}"/usr/lib/systemd/system/playit.service
install -Dm644 LICENSE.txt "${pkgdir}"/usr/share/licenses/"${pkgname}"/LICENSE
install -Dm644 linux/logrotate.conf "${pkgdir}"/etc/logrotate.d/playit
install -Dm644 ../tmpfiles.conf "${pkgdir}"/usr/lib/tmpfiles.d/playit.conf
}
|