PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Magnus Anderssen <magnus at magooweb dot com>
# Contributor: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: John N Bilbrey <beelzebud@gmail.com>

pkgname=plug
pkgver=1.4.5
pkgrel=1
pkgdesc="Software for the Fender Mustang series of guitar amplifiers."
arch=('x86_64')
url="https://github.com/offa/plug"
license=('GPL3')
depends=('qt5-base' 'libusb')
makedepends=('cmake')
checkdepends=('gtest')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('714ba2786de4e501b19285207ab43ecb6283a6a7f2816c1efb9ddcfca7579779')

prepare() {
	cd "$pkgname-$pkgver"
	sed -i '/Exec/d;s/Path/Exec/' cmake/plug.desktop
	sed -i 's|/lib|/usr/lib|g;/plug-config/s|share/plug/cmake|lib/cmake/plug|' cmake/Install.cmake
}

build() {
	cmake \
		-B build \
		-S "$pkgname-$pkgver" \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DCMAKE_BUILD_TYPE=None \
		-DLTO=ON \
		-Wno-dev
	make -C build
}

check() {
	make -C build unittest
}

package() {
	make -C build install DESTDIR="$pkgdir/"
}