blob: 191fd9847118f79d00062aea19f959a58e1c11ba (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Sven Karsten Greiner <sven@sammyshp.de>
pkgname=plus42
pkgver=1.2.7
pkgrel=1
pkgdesc="Advanced scientific programmable calculator, based on Free42"
arch=('x86_64')
url="https://thomasokken.com/plus42/"
license=('GPL-2.0-only')
depends=('gtk3')
source=("http://thomasokken.com/plus42/upstream/$pkgname-upstream-$pkgver.tgz"
"plus42.desktop")
md5sums=('927546836def0fcc9fed1b99854a6e56'
'ba6d9ff8d83e9a244b5da63acbfc018e')
build() {
cd "$srcdir/$pkgname-upstream-$pkgver/gtk"
# build both bin and dec version
make cleaner
make
make clean
make BCD_MATH=1
}
package() {
cd "$srcdir/$pkgname-upstream-$pkgver/gtk"
install -Dm755 plus42bin "$pkgdir/usr/bin/plus42bin"
install -Dm755 plus42dec "$pkgdir/usr/bin/plus42dec"
install -Dm644 README.txt "$pkgdir/usr/share/doc/$pkgname/README_GTK"
install -Dm644 ../README "$pkgdir/usr/share/doc/$pkgname/README"
install -Dm644 icon-48x48.xpm "$pkgdir/usr/share/icons/hicolor/48x48/apps/plus42.xpm"
install -Dm644 icon-128x128.xpm "$pkgdir/usr/share/icons/hicolor/128x128/apps/plus42.xpm"
ln -s /usr/bin/plus42dec "$pkgdir/usr/bin/plus42"
cd ../skins
for x in Plus42.* README.txt; do
install -Dm644 $x "$pkgdir/usr/share/$pkgname/skins/$x"
done
install -Dm644 "$srcdir/plus42.desktop" "$pkgdir/usr/share/applications/com.thomasokken.plus42.desktop"
}
|