PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

# Maintainer: Rod Kay <rodakay5 at gmail dot com>

pkgname=polyorb
pkgdesc='Provides the Distributed Systems Annex (DSA) to build distributed applications with Ada.'
pkgver=20240520
pkgrel=1

arch=(i686 x86_64)
url=https://github.com/AdaCore/PolyORB
license=(GPL)

depends=(gcc-ada 
         xmlada
         gnatcoll-core
         openssl)
         
makedepends=(gprbuild
             autoconf
             automake
             python-sphinx
             python-sphinx_rtd_theme
             texlive-meta)

source=(git+https://github.com/AdaCore/PolyORB.git#branch=24.2
        patch-Makefile.in)

sha256sums=(SKIP
            c0703efe44949b5adb1be9fcb44110a132fbca81dda690a6623bc326df94328a)


prepare()
{
  cd $srcdir/PolyORB
  
  patch -p1 -i ../patch-Makefile.in

  support/reconfig

  # 'support/reconfig' does not generate the 'compile' and 'missing' files, so create them.
  #
  touch support/compile
  touch support/missing
}


build() 
{
  cd $srcdir/PolyORB

  CFLAGS="${CFLAGS//-Wformat}"
  CFLAGS="${CFLAGS//-Werror=format-security}"

  ./configure --prefix=/usr                                             \
              --enable-warnings=n                                       \
              --with-gprbuild=yes                                       \
              --with-gnatcoll=yes                                       \
              --with-appli-perso="corba dsa moma"                       \
              --with-proto-perso="giop soap"                            \
              --with-corba-services="event ir naming notification time" \
              --with-openssl

  make -j1
  make -j1 docs
}


package()
{
  cd $srcdir/PolyORB

  DESTDIR=$pkgdir make -j1 install all
}