blob: b2a7135c3f690f71edc6d48f99a2f238735ade34 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Jefferson Gonzalez <jgmdev@gmail.com>
pkgname=pragtical
pkgver=3.5.2
pkgrel=1
pkgdesc='The practical and pragmatic code editor.'
arch=('x86_64')
url="https://github.com/pragtical/pragtical"
license=('MIT')
depends=(
# Editor Dependencies
'luajit' 'sdl2' 'freetype2' 'pcre2' 'uchardet' 'hicolor-icon-theme'
# Plugin Manager Dependencies
'lua' 'zlib' 'mbedtls2' 'libgit2' 'libzip'
)
makedepends=('meson>=0.58')
source=(
"https://github.com/pragtical/pragtical/archive/refs/tags/v$pkgver.tar.gz"
)
sha256sums=('95050aaa879f05c5ca765d53cfa547b1e1967a60e9a10e8c92bb63d473f51d48')
build() {
cd "pragtical-$pkgver"
arch-meson --wrap-mode default --buildtype release -Duse_system_lua=true build
meson compile -C build
}
package() {
cd "pragtical-$pkgver"
DESTDIR="$pkgdir" meson install -C build
mkdir -p "$pkgdir/usr/share/licenses/$pkgname/"
ln -s "/usr/share/doc/pragtical/licenses.md" "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
}
|