blob: e08e4318f43c12a0c679567cc1accde6a9d1bd9f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Paulo Matias <matias@ufscar.br>
# Contributor: xiota
_pkgname="prjapicula"
pkgname="$_pkgname-git"
pkgver=0.15.r33.g15614ef
_fuzzerver=1.9.8
pkgrel=1
pkgdesc="Project Apicula bitstream documentation for Gowin FPGAs"
url="https://github.com/YosysHQ/apicula"
_pkgsrc="apicula"
_fuzzer="fuzzer-$_fuzzerver"
_fuzzerimg="docker.io/pepijndevos/apicula:$_fuzzerver"
source=(
"$_pkgsrc"::"git+$url.git"
)
sha256sums=(
'SKIP'
)
license=('MIT')
arch=('x86_64')
depends=(
'python'
'python-crc' # AUR
'python-numpy'
'python-openpyxl'
'python-pandas'
'python-pillow'
)
makedepends+=(
'git'
'python-build'
'python-installer'
'python-setuptools'
'python-setuptools-scm'
'python-wheel'
'apptainer'
)
provides=("$_pkgname=${pkgver%%.r*}")
conflicts=("$_pkgname")
pkgver() {
cd "$_pkgsrc"
git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z]*' \
| sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
}
prepare() {
apptainer pull -F $_fuzzer.sif docker://$_fuzzerimg
apptainer sif dump 4 $_fuzzer.sif >$_fuzzer.squashfs
mkdir -p $_fuzzer
unsquashfs -dest $_fuzzer $_fuzzer.squashfs usr/src/gowin 'usr/lib/x86_64-linux-gnu/libfontconfig.so*'
}
build() {
cd "$_pkgsrc"
LD_LIBRARY_PATH="$srcdir/$_fuzzer/usr/lib/x86_64-linux-gnu" \
GOWINHOME="$srcdir/$_fuzzer/usr/src/gowin" \
make
python -m build --wheel --no-isolation --skip-dependency-check
}
package() {
cd "$_pkgsrc"
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|