PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: Giacomo Vercesi <mrjackv@hotmail.it>
# Contributor: Chris Simons < chris at simonsmail dot net >

pkgname=("protonfixes-git")
pkgver=1.0.15.r128.gc121a1d
pkgrel=1
pkgdesc="A module for applying fixes at runtime to unsupported games with Steam Proton without changing game installation files - git version"
arch=("any")
url="https://github.com/simons-public/protonfixes"
license=("BSD")
provides=("protonfixes")
conflicts=("protonfixes")
makedepends=("git" "python-setuptools")
optdepends=('wine: win32 proton prefix support'
            'winetricks: winetricks support'
            'python-cef: splash progress dialog - deprecated'
            'python-kivy: splash progress dialog'
            'kdialog: splash progress dialog'
            'zenity: splash progress dialog')
source=("${pkgname}::git+https://github.com/simons-public/protonfixes#branch=master")
md5sums=('SKIP')

pkgver() {
    cd "${srcdir}/${pkgname}"
    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "${srcdir}/${pkgname}"
    python setup.py build
}

package() {
    cd "${srcdir}/${pkgname}"
    python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
}