PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82

# Maintainer: taotieren <admin@taotieren.com>

pkgname=proxmark3gui-git
pkgver=0.2.8.r0.ge2fb189
pkgrel=16
pkgdesc="A cross-platform GUI for Proxmark3 client | 为 PM3 设计的图形界面"
arch=('x86_64')
url="https://github.com/wh201906/Proxmark3GUI"
license=('LGPL-2.1-Only')
provides=(${pkgname%-git})
conflicts=(${pkgname%-git})
depends=(qt5-serialport)
makedepends=(git
            qt5-tools)
optdepends=("proxmark3-iceman: RRG / Iceman repo - Proxmark3 RDV4.0 and other Proxmark3 platforms.")
source=("${pkgname}::git+${url}.git")
sha256sums=('SKIP')

pkgver() {
    cd "${srcdir}/${pkgname}/"
    git describe --long --tags | sed 's/V//g;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare()
{
    git -C "${srcdir}/${pkgname}" clean -dfx
}

build() {
    cd "${srcdir}/${pkgname}/src"
    qmake -makefile -o Makefile "CONFIG+=release"
    make
}

package() {
    cd "${srcdir}/${pkgname}/src"
    export INSTALL_ROOT="${pkgdir}"
    make install

    install -dm0755 "${pkgdir}/usr/bin"
    ln -sf /opt/Proxmark3GUI/bin/Proxmark3GUI "${pkgdir}/usr/bin/${pkgname%-git}"

    cd "${srcdir}/${pkgname}"
    cp -rv config "${pkgdir}/opt/Proxmark3GUI"

    install -Dm0644 "${srcdir}/${pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname%-git}/LICENSE"

    install -Dm0644 /dev/stdin "${pkgdir}/usr/share/metainfo/io.github.wh201906.proxmark3gui.metainfo.xml" << EOF
<?xml version="1.0" encoding="UTF-8"?>
<component type="desktop-application">
  <id>io.github.wh201906.proxmark3gui</id>

  <name>${pkgname%-git}</name>
  <summary>${pkgname%-git}</summary>

  <metadata_license>MIT</metadata_license>
  <project_license>LGPL-2.1</project_license>

  <description>
    <p>
      ${pkgdesc}
    </p>
  </description>

  <launchable type="desktop-id">io.github.wh201906.proxmark3gui.desktop</launchable>
</component>
EOF

    install -Dm0644 /dev/stdin "${pkgdir}/usr/share/applications/io.github.wh201906.proxmark3gui.desktop" << EOF
[Desktop Entry]
Version=1.0
Type=Application

Name=${pkgname%-git}
Comment=${pkgname%-git}
Categories=Network;Qt;NFC;

Icon=${pkgname%-git}
Exec=${pkgname%-git}
Terminal=false
EOF
}