blob: 1fc6b695a30c66a7e2846f45a6482f49953314f9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Guilhem Saurel <guilhem.saurel@laas.fr>
_org='Simple-Robotics'
_pkgname='proxsuite'
pkgname=("$_pkgname" "$_pkgname-docs")
pkgver=0.7.1
pkgrel=1
pkgdesc="The Advanced Proximal Optimization Toolbox"
arch=('any')
url="https://github.com/$_org/$_pkgname"
license=('BSD-2-Clause')
depends=()
optdepends=()
makedepends=('cmake' 'graphviz' 'git' 'eigen' 'simde')
checkdepends=('libmatio')
source=($url/releases/download/v$pkgver/$_pkgname-$pkgver.tar.gz{,.sig})
sha256sums=('8c7f89d2c7a52e157ba5fb20ff2a73117574d7ec629a11f9c5f05b549c59bf7b'
'SKIP')
validpgpkeys=(
'A031AD35058955293D54DECEC45D22EF408328AD' # https://github.com/jcarpent.gpg
'F534E75540B2E7D24F99746987CFFF3D0D73CC93' # https://github.com/jcarpent.gpg
'1462AF00C9CF3C9E7AFC905E63380359F089A579' # https://github.com/jorisv.gpg
)
build() {
cmake -B "build-$pkgver" -S "$pkgbase-$pkgver" \
-DCMAKE_INSTALL_LIBDIR=lib \
-DCMAKE_INSTALL_PREFIX=/usr \
-DINSTALL_DOCUMENTATION=ON \
-DBUILD_DOCUMENTATION=ON \
-Wno-dev
cmake --build "build-$pkgver"
}
check() {
cmake --build "build-$pkgver" -t test
}
package_proxsuite() {
DESTDIR="$pkgdir/" cmake --build "build-$pkgver" -t install
rm -rf "$pkgdir/usr/share/doc"
install -Dm644 "$pkgbase-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
package_proxsuite-docs() {
DESTDIR="$pkgdir/" cmake --build "build-$pkgver" -t install
rm -rf $pkgdir/usr/{lib,include,bin,share/{"$_pkgname",ament,ament_index}}
install -Dm644 "$pkgbase-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|