blob: f3dfa077a0a0cf34a53d0a470d1e9dfa2d91f4aa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
# Contributor: Caltlgin Stsodaat <contact@fossdaily.xyz>
## GPG key from https://github.com/thombashi.gpg
pkgname=python-appconfigpy
pkgver=1.0.2
pkgrel=4
pkgdesc='Python library to create/load an application configuration file'
arch=('any')
url='https://github.com/thombashi/appconfigpy'
license=('MIT')
depends=('python')
makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
checkdepends=('python-pytest')
source=(
"$pkgname-$pkgver.tar.gz::https://files.pythonhosted.org/packages/source/a/appconfigpy/appconfigpy-$pkgver.tar.gz"
"$pkgname-$pkgver.tar.gz.asc::https://files.pythonhosted.org/packages/source/a/appconfigpy/appconfigpy-$pkgver.tar.gz.asc"
'remove-examples.patch')
sha256sums=('114336a9e01d04c4818fd4512f470f611aabf2ea5925b7ba5a6ca25c70f173d8'
'SKIP'
'cf3930e36be488e21655e84ee246676b3ff293bc98253113545fdd5d275f154a')
validpgpkeys=('ACEC3954F31619D7288C17B07BAC46763C91BB7A') ## Tsuyoshi Hombashi
prepare() {
patch -p1 -d "appconfigpy-$pkgver" < remove-examples.patch
}
build() {
cd "appconfigpy-$pkgver"
python -m build --wheel --no-isolation
}
check() {
cd "appconfigpy-$pkgver"
PYTHONPATH="$PWD" pytest -x --disable-warnings
}
package() {
export PYTHONHASHSEED=0
cd "appconfigpy-$pkgver"
python -m installer --destdir="$pkgdir/" dist/*.whl
install -Dm644 'README.rst' -t "${pkgdir}/usr/share/doc/${pkgname}"
local _site="$(python -c 'import site; print(site.getsitepackages()[0])')"
install -d "$pkgdir/usr/share/licenses/$pkgname/"
ln -s \
"$_site/appconfigpy-$pkgver.dist-info/LICENSE" \
"$pkgdir/usr/share/licenses/$pkgname/"
}
# vim: ts=2 sw=2 et:
|