PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Bipin Kumar <kbipinkumar@pm.me>
# Contributor: Evgeniy Alekseev <arcanis.arch at gmail dot com>
# Contributor: Stunts <f.pinamartins at gmail dot com>
# Contributor: damir <damir at archlinux dot org>

pkgname=python-biopython
_pkgname=biopython
pkgver=1.85
pkgrel=1
pkgdesc="Freely available Python tools for computational molecular biology"
arch=('x86_64')
url="http://www.biopython.org"
license=('LicenseRef-Biopython License')
makedepends=('python-setuptools')
checkdepends=('python-scipy' 'python-rdflib' 'python-igraph' 'python-reportlab' 'python-networkx' 'python-mmtf' 'python-matplotlib' 'python-coverage')
depends=('python-numpy' 'glibc' 'python' 'python-scipy' 'python-pillow')
# optdepends from https://github.com/biopython/biopython?tab=readme-ov-file#optional-dependencies
optdepends=('python-mysql-connector: for BioSQL module'
            'python-reportlab: for graph generation'
            'python-networkx: for certain niche functions in Bio.Phylo module'
            'python-matplotlib: to plot phylogenetic trees.'
            'python-rdflib: CDAO parser under Bio.Phylo module'
           )
source=("http://www.biopython.org/DIST/${_pkgname}-${pkgver}.tar.gz"
       )
sha512sums=('a9bff4fdf34f71f74f35a9bbf25887d6fcf84622d77854e11b0da418b6ff88c7d6e49474d82ca2e4da782ea07cc28f03b43b219b798a806ab02e11af21cd9dab')
options=(!debug)

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  python setup.py build
}

check() {
  local pyver=$(python -c 'import sys; print(*sys.version_info[:2], sep="")')
  local impl=$(python -c 'import platform; print(platform.python_implementation().lower())')
  local machine=$(python -c 'import platform; print(platform.machine())')
  cd "${srcdir}/${_pkgname}-${pkgver}"
  python setup.py test
}
package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  python setup.py install --root="${pkgdir}"
  install -Dm644 "LICENSE.rst" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}