PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Blair Bonnett <blair.bonnett@gmail.com>

pkgname=python-copier-templates-extensions
pkgdesc='Jinja2 extension for Copier to use relative file paths'
pkgver=0.3.1
pkgrel=1
url='https://github.com/copier-org/copier-templates-extensions'
license=('ISC')
arch=('any')

depends=(
  'python-copier'
  'python-jinja'
)
makedepends=(
  'git'
  'python-build'
  'python-installer'
  'python-pdm-backend'
)
checkdepends=(
  'mkdocstrings'
  'python-griffe'
  'python-pytest'
)

source=(
  "git+https://github.com/copier-org/copier-templates-extensions.git#tag=$pkgver"
)
sha256sums=(
  '1a05039f5c155c98bdcf2cff5c3c18106f81ef437266aa53d05fbf298f6eabce'
)

build() {
  cd copier-templates-extensions
  python -m build --no-isolation --wheel
}

check() {
  cd copier-templates-extensions
  rm -rf test-env
  python -m venv --system-site-packages test-env
  test-env/bin/python -m installer "dist/copier_templates_extensions-$pkgver"-*.whl
  test-env/bin/python -m pytest -v
}

package() {
  cd copier-templates-extensions
  python -m installer --destdir="$pkgdir" "dist/copier_templates_extensions-$pkgver"-*.whl
  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}