PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Maintainer: William J. Bowman <aur@williamjbowman.com>
# Contributer: Felix Yan <felixonmars@archlinux.org>

pkgbase=python-defusedxml-git
pkgname=("python-defusedxml-git" "python2-defusedxml-git")
pkgver=v0.4.1.r5.g39d2ad3
pkgrel=1
pkgdesc="XML bomb protection for Python stdlib modules"
arch=('any')
url='https://github.com/AdamWill/defusedxml'
license=('Python')
makedepends=('python' 'python2')
source=('defusedxml::git+https://github.com/AdamWill/defusedxml#branch=py36-iterparse')
md5sums=('SKIP')

pkgver() {
  cd defusedxml
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cp -a "defusedxml"{,-py2}
}

package_python-defusedxml-git() {
  depends=('python')
  conflicts=('python-defusedxml')
  provides=('python-defusedxml')

  cd defusedxml
  python3 setup.py install --root="${pkgdir}" --optimize=1
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_python2-defusedxml-git() {
  depends=('python2')
  conflicts=('python2-defusedxml')
  provides=('python2-defusedxml')

  cd defusedxml-py2
  python2 setup.py install --root="${pkgdir}" --optimize=1
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}