blob: 93e780593a72a5a038dab65c86a66ffd0b0e14ba (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Daniel Bershatsky <bepshatsky@yandex.ru>
# Maintainer: @xiota
# Contributor: Alexander F. Rødseth <xyproto@archlinux.org>
_module="diffusers"
_pkgname="python-$_module"
pkgname="$_pkgname"
pkgver=0.31.0
pkgrel=2
pkgdesc='Pretrained diffusion models for image and audio generation in PyTorch'
url='https://github.com/huggingface/diffusers'
license=('Apache-2.0')
arch=('any')
groups=('huggingface')
depends=(
'python-filelock'
'python-huggingface-hub'
'python-numpy'
'python-pillow'
'python-regex'
'python-requests'
'python-safetensors'
)
optdepends=(
'python-accelerate: multi-GPU and TPU training support'
'python-datasets: datasets and data loading'
'python-flax: JAX/FLAX support'
'python-peft: parameter efficient fine-tunning'
'python-pytorch: PyTorch support'
'python-tensorflow: TensorFlow support'
)
makedepends=(
'python-build'
'python-installer'
'python-setuptools'
'python-wheel'
)
_pkgsrc="$_module-$pkgver"
_pkgext="tar.gz"
source=("$_pkgsrc.$_pkgext"::"$url/archive/refs/tags/v$pkgver.$_pkgext")
sha256sums=('31c4e402f6d29e6b2741c8cad87f0b5307393ffabc5bbe843824c182b3408989')
build() {
cd "$_pkgsrc"
python -m build --no-isolation --wheel
}
check() {
PYTHONPATH=$srcdir/$_pkgsrc/src python -c 'import diffusers'
}
package() {
cd "$_pkgsrc"
python -m installer --destdir="$pkgdir" dist/*.whl
}
|