blob: 41ed1a0add838b36c6c256018ddff35c384f3a45 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# -*- sh -*-
# Maintainer: Klaus Alexander Seistrup <$(echo 0x1fd+d59decfa=40 | tr 0-9+a-f=x ka-i@p-u.l)>
pkgname='python-fastfeedparser-git'
_pkgname="${pkgname/-git/}"
_srcname="${_pkgname/python-/}"
pkgver=0.3.7.r57.2da82e8
pkgrel=2
epoch=1
pkgdesc='High performance RSS, Atom and RDF parser in Python (built from latest git commit)'
arch=('any')
url='https://github.com/kagisearch/fastfeedparser'
license=('MIT') # SPDX-License-Identifier: MIT
makedepends=(
'awk'
'git'
'python-build'
'python-installer'
'python-setuptools>=67.0'
'python-wheel'
)
depends=(
'python>=3.7'
'python-dateparser'
'python-dateutil'
'python-lxml'
)
source=("git+$url.git")
provides=("$_pkgname")
conflicts=("${provides[@]}")
sha256sums=('SKIP')
pkgver() {
cd "$_srcname"
_ver=$(awk '/^version = / { print $3 }' setup.cfg)
test -n "$_ver" && printf '%s.' "$_ver"
printf 'r%s.%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}
prepare() {
cd "$_srcname"
sed -i 's/"setuptools~=67\.0"/"setuptools>=67\.0"/g' pyproject.toml
}
build() {
cd "$_srcname"
python -m build --wheel --no-isolation
}
package() {
cd "$_srcname"
python -m installer --destdir="$pkgdir" dist/*.whl
install -vDm0644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
install -vDm0644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
}
# eof
|