PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

# Maintainer: haxibami <contact at haxibami dot net>

pkgname=python-pycrashreport
_pkgname="${pkgname#python-}"
pkgver=1.2.6
pkgrel=2
pkgdesc="Python3 parser for Apple's crash reports"
arch=('any')
url='https://github.com/doronz88/pycrashreport'
license=('GPL-3.0-or-later')
depends=('python' 'python-click' 'python-cached-property' 'python-la_panic')
makedepends=('python-build' 'python-wheel' 'python-installer' 'python-setuptools' 'python-setuptools-scm')
checkdepends=('python-pytest')
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz")
sha256sums=('fbfc667753cec3be7888aeefc8d9c8dba8f7f27fdc24656d10fe6a0e8598ce49')

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  export SETUPTOOLS_SCM_PRETEND_VERSION="$pkgver"
  python -m build --wheel --no-isolation
}

check() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  python -m pytest
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  python -m installer --destdir="$pkgdir" dist/*.whl
}