blob: b9fc76d0e7fb2aa17ce871f18c3e22ce119872ce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Xeonacid <h.dwwwwww@gmail.com>
_name=certvalidator
pkgname=python-pyhanko-${_name}
pkgver=0.26.8
pkgrel=1
pkgdesc="Python library for validating X.509 certificates and paths"
arch=(any)
url="https://github.com/MatthiasValvekens/${_name}"
license=(MIT)
depends=(python python-asn1crypto python-oscrypto python-cryptography python-uritools python-requests python-aiohttp)
makedepends=(python-build python-installer python-setuptools python-wheel)
checkdepends=(python-pytest python-freezegun python-pytest-asyncio)
source=(${_name}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz)
sha512sums=('97e1d14271f63947f0d9a87ddb4826f0cae006713a22d8c68110c0694e7a611cfbeb8ccea27509889319c76f2a91af6ec2cf5611b52672a3cdb530a7eebde3e8')
build() {
cd $_name-$pkgver
python -m build --wheel --no-isolation
}
check(){
cd $_name-$pkgver
python -m venv --system-site-packages test-env
test-env/bin/python -m installer dist/*.whl
test-env/bin/python -m pytest -vv tests
}
package() {
cd $_name-$pkgver
python -m installer --destdir="$pkgdir" dist/*.whl
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
install -Dm644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
}
|