blob: 1ebf4a2a6652b23a2fcc24c1a922ce005b00d7f4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: George Rawlinson <george@rawlinson.net.nz>
pkgname=python-pylightxl
pkgver=1.61
pkgrel=1
pkgdesc='Minimal functionality Excel library'
arch=('any')
url='https://github.com/PydPiper/pylightxl'
license=('MIT')
depends=('python')
makedepends=(
'git'
'python-build'
'python-installer'
'python-wheel'
'python-setuptools'
)
checkdepends=('python-pytest')
_commit='563e616fa122022d168849a3862cc0e486887dd5'
source=("$pkgname::git+$url.git#commit=$_commit")
b2sums=('SKIP')
pkgver() {
cd "$pkgname"
git describe --tags | sed 's/^v//'
}
build() {
cd "$pkgname"
python -m build --wheel --no-isolation
}
check() {
cd "$pkgname"
PYTHONPATH="$(pwd)/src:$PYTHONPATH" pytest -v
}
package() {
cd "$pkgname"
python -m installer --destdir="$pkgdir" dist/*.whl
# license
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}
|