blob: 3429674de6b6ee609673c185023322781f2c1f53 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
# Contributor: Antonio Rojas <arojas@archlinux.org>
# Contributor: Christian Hesse <mail@eworm.de>
# Contributor: Robert Knauer <robert@privatdemail.net>
_base=pyodbc
pkgname=python-${_base}
pkgver=5.2.0
pkgrel=1
pkgdesc="ODBC module for Python"
arch=(x86_64)
url="https://github.com/mkleehammer/${_base}"
license=(MIT)
depends=(python unixodbc)
makedepends=(python-build python-installer python-setuptools python-wheel)
source=(${url}/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
sha512sums=('645dc77c0b767f05bc959b3ba05696ca7bcec5b772f2863d74686686c9b22b73aac86693d6bdeb0df7559cd6d5f0bd909c7119808389830a322710e366e398e9')
prepare() {
echo "Version: ${pkgver}.0" >${_base}-${pkgver}/PKG-INFO
}
build() {
cd ${_base}-${pkgver}
python -m build --wheel --skip-dependency-check --no-isolation
}
package() {
cd ${_base}-${pkgver}
PYTHONPYCACHEPREFIX="${PWD}/.cache/cpython/" python -m installer --destdir="${pkgdir}" dist/*.whl
install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
rm "$pkgdir${site_packages}"/pyodbc.pyi
}
|