PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

# Contributor: Auerhuhn
# Maintainer: Strykar <strykar@hotmail.com>

_gitpkgname=RouterOS-api
pkgname="python-${_gitpkgname,,}"
pkgver=0.18.1
pkgrel=1
pkgdesc="Python API to Mikrotik RouterBoard devices"
arch=('any')
url="https://github.com/socialwifi/RouterOS-api"
license=('MIT')
depends=('python')
makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
source=("${_gitpkgname}-${pkgver}.tar.gz::https://github.com/socialwifi/RouterOS-api/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('6b3bb3db339dae00600535e8932ad0216d3416900d7be3f803f09347711cade3')

prepare() {
    cd "${_gitpkgname}-${pkgver}"
    sed -i "s/\(find_packages\)()/\1(exclude=['tests'])/" setup.py
}

build() {
    cd "${_gitpkgname}-${pkgver}"
    python -m build --wheel --no-isolation
}

package() {
    cd "${_gitpkgname}-${pkgver}"
    python -m installer --destdir="$pkgdir" dist/*.whl
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}