blob: 40168dbe4feecae0e4be4897aa6faf2f7305ba58 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Astro Benzene <universebenzene at sina dot com>
pkgbase=python-stsci.tools
_pname=${pkgbase#python-}
_pyname=${_pname//./_}
pkgname=("python-${_pname}")
pkgver=4.1.1
pkgrel=1
pkgdesc="Collection of STScI utility functions"
arch=('any')
url="https://stscitools.readthedocs.io"
license=('BSD-3-Clause')
makedepends=('python-setuptools-scm'
'python-wheel'
'python-build'
'python-installer')
checkdepends=('python-pytest-astropy-header'
'python-pytest-doctestplus'
'python-astropy'
'tk')
source=("https://files.pythonhosted.org/packages/source/${_pyname:0:1}/${_pyname}/${_pyname}-${pkgver}.tar.gz")
md5sums=('dc80e68dfb3238a2f4991d6ecacf2071')
build() {
cd ${srcdir}/${_pyname}-${pkgver}
python -m build --wheel --no-isolation
}
check() {
cd ${srcdir}/${_pyname}-${pkgver}
pytest || warning "Tests failed" # -vv -l -ra --color=yes -o console_output_style=count
}
package_python-stsci.tools() {
depends=('python-astropy>=5.0.4' 'python-packaging')
optdepends=('python-stsci.tools-doc: Documentation for STScI Tools')
provides=("python-stscitools=${pkgver}")
conflicts=('python-stscitools')
cd ${srcdir}/${_pyname}-${pkgver}
install -D -m644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE.md
install -D -m644 -t "${pkgdir}/usr/share/doc/${pkgname}" README.md
python -m installer --destdir="${pkgdir}" dist/*.whl
}
|