blob: 985ada29691e6aa111cf6d32e2842217dee7ccc2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Maintainer: Astro Benzene <universebenzene at sina dot com>
# Contributor: Miguel de Val-Borro <miguel dot deval at gmail dot com>
pkgbase=python-synphot
_pyname=${pkgbase#python-}
pkgname=("python-${_pyname}" "python-${_pyname}-doc")
pkgver=1.4.0
pkgrel=1
pkgdesc="Synthetic Photometry using Astropy"
arch=('i686' 'x86_64')
url="https://synphot.readthedocs.io"
license=('BSD-3-Clause')
makedepends=('python-setuptools-scm'
'python-wheel'
'python-build'
'python-installer'
'python-numpy'
'python-sphinx-astropy'
'python-matplotlib'
'python-astropy'
'python-scipy'
'graphviz')
checkdepends=('python-pytest-astropy-header'
'python-pytest-doctestplus'
'python-pytest-remotedata'
'python-dust-extinction'
'python-specutils') # astropy scipy already in makedepends
source=("https://files.pythonhosted.org/packages/source/${_pyname:0:1}/${_pyname}/${_pyname}-${pkgver}.tar.gz")
md5sums=('c6ce9f25d94fcec45d87f0678b64604c')
get_pyver() {
python -c "import sys; print('$1'.join(map(str, sys.version_info[:2])))"
}
build() {
cd ${srcdir}/${_pyname}-${pkgver}
python -m build --wheel --no-isolation --skip-dependency-check
msg "Building Docs"
ln -rs ${srcdir}/${_pyname}-${pkgver}/${_pyname/-/_}*egg-info \
build/lib.linux-${CARCH}-cpython-$(get_pyver)/${_pyname/-/_}-${pkgver}-py$(get_pyver .).egg-info
PYTHONPATH="../build/lib.linux-${CARCH}-cpython-$(get_pyver)" make -C docs html
}
check() {
cd ${srcdir}/${_pyname}-${pkgver}
mv {,_}${_pyname}
pytest "build/lib.linux-${CARCH}-cpython-$(get_pyver)" docs || warning "Tests failed" # -vv -l -ra --color=yes -o console_output_style=count --remote-data=any
}
package_python-synphot() {
depends=('python-numpy>=1.23'
'python-astropy>=6'
'python-scipy>=1.9')
optdepends=('python-matplotlib: Plotting support'
'python-specutils>=0.7: Manipulating spectroscopic data'
'python-synphot-doc: Documentation for synphot')
cd ${srcdir}/${_pyname}-${pkgver}
install -D -m644 -t "${pkgdir}/usr/share/licenses/${pkgname}" LICENSE.rst
install -D -m644 -t "${pkgdir}/usr/share/doc/${pkgname}" README.rst
python -m installer --destdir="${pkgdir}" dist/*.whl
}
package_python-synphot-doc() {
pkgdesc="Documentation for Python Synthetic Photometry (synphot)"
arch=('any')
cd ${srcdir}/${_pyname}-${pkgver}/docs/_build
install -D -m644 ../../LICENSE.rst -t "${pkgdir}/usr/share/licenses/${pkgname}"
install -d -m755 "${pkgdir}/usr/share/doc/${pkgbase}"
cp -a html "${pkgdir}/usr/share/doc/${pkgbase}"
}
|