PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

# Maintainer: Mohamed Amine Zghal (medaminezghal) <medaminezghal at outlook dot com>

_name=testcontainers
pkgname=python-${_name}
pkgver=4.9.1
pkgrel=2
pkgdesc='Python library for throwaway instances of anything that can run in a Docker container.'
arch=('any')
url='https://github.com/testcontainers/testcontainers-python'
license=('Apache-2.0')
source=("${url}/archive/refs/tags/${_name//-/_}-${pkgver}.tar.gz")
sha256sums=('df83261ff1217fa1ff85392a3f76b9a628cecb63a4473bf41b1a0fa48d6c98e0')
depends=('python>=3.9' 'python-docker' 'python-urllib3' 'python-wrapt' 'python-typing_extensions' 'python-dotenv')
makedepends=('python-poetry-core' 'python-build' 'python-installer' 'python-wheel')
checkdepends=('python-pytest' 'python-pytest-cov' 'python-anyio' 'python-psycopg2' 'python-pg8000' 'python-sqlalchemy' 'python-psycopg' 'python-cassandra-driver' 'python-pytest-asyncio' 'python-kafka-ng' 'python-hvac' 'python-pymilvus' 'python-httpx' 'python-paho-mqtt' 'python-sqlalchemy-cockroachdb' 'python-paramiko' 'python-types-paramiko' 'python-pytest-mock' )
optdepends=('python-arango: arangodb'
            'python-botto3: aws - localstack'
            'python-httpx: aws - generic - test_module_import'
            'python-azure-storage-blob: azurite'
            'python-clickhouse-driver: clickhouse'
            'python-azure-cosmos: cosmosdb'
            'python-sqlalchemy: db2 - mssql - mysql - oracle - oracle-free'
            'python-ibm-db-sa: db2'
            'python-redis: generic - redis'
            'python-google-cloud-pubsub: google'
            'python-google-cloud-datastore: google'
            'python-influxdb: influxdb'
            'python-influxdb-client: influxdb'
            'python-kubernetes: k3s'
            'python-pyyaml: k3s'
            'python-keycloak: keycloak'
            'python-cryptography: mailpit - sftp'
            'python-minio: minio'
            'python-pymongo: mongodb'
            'python-pymssql: mssql'
            'python-pymysql: mysql'
            'python-nats: nats'
            'python-neo4j: neo4j'
            'python-opensearch: opensearch'
            'python-oracledb: oracle - oracle-free'
            'python-qdrant-client: qdrant'
            'python-pika: pika'
            'python-bcrypt: registry'
            'python-selenium: selenium'
            'python-cassandra-driver: scylla'
            'python-weaviate-client: weaviate'
            'python-chromadb-client: chroma'
            'python-trino: trino')

build() {
  cd "${srcdir}"/${_name//-/_}-${pkgname}-${pkgver}
  python -m build --wheel --no-isolation
}

check(){
  local pytest_options=(
    -vv
    --override-ini="addopts="
  )
  cd "${srcdir}"/${_name//-/_}-${pkgname}-${pkgver}
  python -m venv --system-site-packages test-env
  test-env/bin/python -m installer dist/*.whl
  test-env/bin/python -m pytest "${pytest_options[@]}" core/tests
}

package() {
  cd "${srcdir}"/${_name//-/_}-${pkgname}-${pkgver}
  python -m installer --destdir="$pkgdir" dist/*.whl
}