blob: 9e1c106f637ba0ee08d8cf9803a234db98a82e55 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Maintainer: Claudia Pellegrino <aur ät cpellegrino.de>
pkgname=python-tree-sitter-c-sharp
_gitpkgname=tree-sitter-c-sharp
pkgver=0.23.1
pkgrel=1
pkgdesc='C# grammar for tree-sitter'
arch=('x86_64')
url='https://github.com/tree-sitter/tree-sitter-c-sharp'
license=('MIT')
depends=(
'glibc'
'python'
)
makedepends=(
'python-build'
'python-installer'
'python-setuptools'
'python-wheel'
)
checkdepends=(
'python-pytest'
'python-tree-sitter'
)
source=(
"${_gitpkgname}-${pkgver}.tar.gz::https://github.com/tree-sitter/tree-sitter-c-sharp/archive/v${pkgver}.tar.gz"
)
sha512sums=(
'8b4467d13f7947b38b13ed1b81f09dd6754155d2a0090d557e7252cd103f80de23d6890cc6de7142f39332cd88395b9976b89833232f16582646c96f1d28a31a'
)
build() {
cd "${_gitpkgname}-${pkgver}"
echo >&2 'Building wheel'
python -m build --wheel --no-isolation
}
check() {
cd "${_gitpkgname}-${pkgver}"
python -m venv --system-site-packages test-env
test-env/bin/python -m installer dist/*.whl
echo >&2 'Running unit tests'
test-env/bin/python -m pytest
}
package() {
cd "${_gitpkgname}-${pkgver}"
echo >&2 'Packaging the wheel'
python -I -m installer --destdir="${pkgdir}" dist/*.whl
echo >&2 'Packaging the documentation'
install -D -m 644 -t "${pkgdir}/usr/share/doc/${pkgname}" \
README.md
echo >&2 'Packaging the license'
install -D -m 644 -t "${pkgdir}/usr/share/licenses/${pkgname}" \
LICENSE
}
|