blob: 3ee20b55348215d26073e83a3bd4e6be5ee1a6c4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# -*- sh -*-
# Maintainer: Klaus Alexander Seistrup <$(echo 0x1fd+d59decfa=40 | tr 0-9+a-f=x ka-i@p-u.l)>
pkgname='python-urllib3-future-git'
_pkgname="${pkgname/-git/}"
_srcname="${_pkgname/python-/}"
_srcdir="${_srcname/-/.}"
pkgver=2.12.915.r0.g60af644f
pkgrel=2
pkgdesc='Powerful HTTP 1.1, 2, and 3 client with both sync and async interfaces (built from latest git commit)'
arch=('any')
url='https://github.com/jawah/urllib3.future'
license=('MIT') # SPDX-License-Identifier: MIT
makedepends=(
'git'
'python-build'
'python-hatchling'
'python-installer'
'python-wheel'
)
depends=(
'python'
'python-brotli'
'python-h11'
'python-idna'
'python-jh2'
'python-pyopenssl'
'python-pysocks'
'python-python-socks'
'python-qh3'
'python-typing_extensions'
'python-wsproto'
'python-zstandard'
)
source=("git+$url.git")
provides=("$_pkgname")
conflicts=("${provides[@]}")
sha256sums=('SKIP')
pkgver() {
cd "$_srcdir"
git describe --tags --long \
| sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$_srcdir"
# We do not wish to conflict with the original python-urllib3
env URLLIB3_NO_OVERRIDE=true python -m build --wheel --no-isolation
}
package() {
cd "$_srcdir"
python -m installer --destdir="$pkgdir" dist/*.whl
install -vDm0644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
install -vDm0644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}
# eof
|