blob: 25343390db05b9516af98f18a402f2e43dce233e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# -*- sh -*-
# Maintainer: Klaus Alexander Seistrup <$(echo 0x1fd+d59decfa=40 | tr 0-9+a-f=x ka-i@p-u.l)>
pkgname='python-valkey-git'
_pkgname="${pkgname/-git/}"
_srcname="${_pkgname/python-/}"
pkgver=6.1.0.r8.g994ed74
pkgrel=3
pkgdesc='Valkey Python client based on a fork of redis-py (built from latest git commit)'
arch=('any')
url='https://github.com/valkey-io/valkey-py'
license=(
'MIT' # SPDX-License-Identifier: MIT (main package)
)
makedepends=(
'git'
'python-build'
'python-installer'
'python-wheel'
)
depends=(
'python>=3.11.3'
'python-cryptography'
'python-pyopenssl'
'python-redis'
'python-requests'
)
source=("git+$url.git")
provides=("$_pkgname")
conflicts=("${provides[@]}")
sha256sums=('SKIP')
pkgver() {
cd "$_srcname-py"
git describe --tags --long | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$_srcname-py"
git clean -dfx
}
build() {
cd "$_srcname-py"
python -m build --wheel --no-isolation
}
package() {
cd "$_srcname-py"
python -m installer --destdir="$pkgdir" dist/*.whl
install -vDm0644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
install -vDm0644 -t "$pkgdir/usr/share/doc/$pkgname" ./*.md
}
# eof
|