PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

pkgname='python-zopfli-git'
pkgdesc='Python bindings for the Zopfli compressor'
pkgver=0.0.8.r0.gfdaf482
pkgrel=1
arch=('x86_64')
license=(Apache-2.0)
depends=(glibc python)
makedepends=(git python-build python-installer python-setuptools python-wheel)
url=https://github.com/anthrotype/py-zopfli
source=("$pkgname::git+$url"
		'git+https://github.com/google/zopfli.git')
sha512sums=(SKIP SKIP)

pkgver () {
	cd "$pkgname"
	(
		set -o pipefail
		git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
		printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
	)
}

prepare () {
	cd "$pkgname"
	git submodule init
	git config submodule.zopfli.url "$srcdir/zopfli"
	git -c protocol.file.allow=always submodule update
}

build () {
	cd "$pkgname"
	python -m build --wheel --no-isolation
}

package () {
	cd "$pkgname"
	python -m installer --destdir="$pkgdir" dist/*.whl
}