PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

# Maintainer: Emmanuel Farhi <emmanuel.farhi.1@gmail.com>
# create Arch package with: makepkg -si
# create .SRCINFO with:     makepkg --printsrcinfo > .SRCINFO
pkgname='qemu-web-desktop'
pkgver=25.02.28
pkgrel=1
pkgdesc="Remote desktop service with virtual machines in a browser (DARTS)."
arch=('x86_64')
url="https://gitlab.com/soleil-data-treatment/soleil-software-projects/$pkgname"
license=('AGPL-3.0-or-later')
makedepends=()
depends=(python-numpy python-setuptools apache mod_itk qemu-desktop bridge-utils qemu-img dnsmasq guestfs-tools perl-cgi perl-list-moreutils perl-sys-cpu perl-sys-meminfo perl-net-dns perl-proc-processtable perl-mail-imapclient perl-ldap perl-json perl-libwww mod_perl novnc websockify perl-proc-background perl-email-valid perl-net-smtps perl-text-qrcode perl-net-ssh2 confget)
source=("git+https://gitlab.com/soleil-data-treatment/soleil-software-projects/${pkgname}.git#tag=v${pkgver}")
md5sums=('SKIP')
install="post_install.install"

package() {
	cd "$pkgname/src"
	make copy DESTDIR="$pkgdir"
	echo "configuration..."
	mkdir -p ${pkgdir}/srv/http/desktop
	ln -sf /usr/share/qemu-web-desktop/html/desktop       ${pkgdir}/srv/http/qemu-web-desktop
	ln -sf /var/lib/qemu-web-desktop/machines             ${pkgdir}/srv/http/desktop/
	ln -sf /var/lib/qemu-web-desktop/machines.html        ${pkgdir}/usr/share/qemu-web-desktop/html/desktop
	sed -i 's|/usr/share/novnc|/usr/share/webapps/novnc|' ${pkgdir}/etc/qemu-web-desktop/config.pl
	# create system-user for itk
	mkdir -p ${pkgdir}/usr/lib/sysusers.d/
	echo "u	_qemu-web-desktop	-	-	/var/lib/qemu-web-desktop" > ${pkgdir}/usr/lib/sysusers.d/qemu-web-desktop.conf
}

# post_install.install script performs the configuration once the package has been installed.