PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Maintainer: Frederic Bezies < fredbezies at gmail dot com>
# Based on old quakespasm-svn PKGBUILD 
# which was last maintained by Mark Vainomaa <mikroskeem round around a mikroskeem dot eu>

pkgname=quakespasm-git
_pkgname=quakespasm
pkgver=0.96.3.r5.gdebadb6a
pkgrel=1
pkgdesc="A modern Quake 1 engine. Forked from Fitzquake and improved in many ways such as Vorbis/MP3 support for music. - Development version"
arch=('i686' 'x86_64')
url="http://quakespasm.sourceforge.net"
license=('GPL2')
depends=('libvorbis' 'libmad' 'sdl2')
makedepends=('subversion')
conflicts=('quakespasm')
provides=('quakespasm')
install=${pkgname}.install
source=('git+https://git.code.sf.net/p/quakespasm/quakespasm')
sha256sums=('SKIP')
options=(!debug)

pkgver() {
    cd "${srcdir}/${_pkgname}"
    git describe --long --tags | sed 's/^quakespasm-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
    cd "${srcdir}/${_pkgname}/Quake/"
    msg "Starting make..."
    make DO_USERDIRS=1 USE_SDL2=1
}

package() {
    cd "${srcdir}/${_pkgname}/Quake/"
    install -D -m 755 quakespasm "${pkgdir}/usr/bin/${pkgname}"
}