blob: ab973d9b8cdd44cb77273fc17353a40539cc220e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=quick-lookup
_app_id=com.github.johnfactotum.QuickLookup
pkgver=2.1.2
pkgrel=1
pkgdesc="Simple GTK dictionary application powered by Wiktionary"
arch=('any')
url="https://github.com/johnfactotum/quick-lookup"
license=('GPL-3.0-or-later')
depends=('gjs' 'gtk4' 'libadwaita' 'webkitgtk-6.0')
makedepends=('meson')
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
sha256sums=('040d3570e5799396ef728402242ab06d8b7dfda4f365a5ae9d20e28d95c4f701')
prepare() {
cd "$pkgname-$pkgver"
# Correct version
sed -i "s/2.1.0/$pkgver/g" meson.build
}
build () {
arch-meson "$pkgname-$pkgver" build
meson compile -C build
}
check() {
cd "$pkgname-$pkgver"
appstreamcli validate --no-net "${_app_id}.appdata.xml"
desktop-file-validate "${_app_id}.desktop"
}
package() {
meson install -C build --destdir "$pkgdir"
}
|