blob: 92af2f56800e60854012339aac6a8e5eb3e1a534 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=quick-webapps
pkgver=0.5.2
pkgrel=1
pkgdesc="Web App Manager for the COSMIC™ desktop written with love and libcosmic."
arch=('x86_64')
url="https://github.com/cosmic-utils/web-apps"
license=('GPL-3.0-or-later')
depends=(
'gcc-libs'
'hicolor-icon-theme'
'libxkbcommon'
'openssl'
)
makedepends=(
'cargo'
'just'
)
conflicts=('cosmic-wam' 'cosmic-webapps')
source=("web-apps-$pkgver.tar.gz::$url/archive/refs/tags/$pkgver.tar.gz")
sha256sums=('a1f282ede5aa880097d4564343e0a05caef01767f08cda3145ab4ec7df329f6a')
prepare() {
cd web-apps-$pkgver
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd web-apps-$pkgver
export RUSTUP_TOOLCHAIN=stable
just build-release --frozen
}
package() {
cd web-apps-$pkgver
just rootdir="$pkgdir" install
}
|