blob: d9ae5576993480707f975dc17c242808373d6f76 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: Guoyi Zhang <guoyizhang at malacology dot net>
_pkgname=arrow
_pkgver=19.0.1.1
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Integration to 'Apache' 'Arrow'"
arch=(x86_64)
url="https://cran.r-project.org/package=$_pkgname"
license=(Apache)
depends=(
arrow
r-assertthat
r-bit64
r-glue
r-purrr
r-r6
r-rlang
r-tidyselect
r-vctrs
)
makedepends=(
r-cpp11
)
checkdepends=(
r-blob
r-curl
r-dplyr
r-hms
r-lubridate
r-reticulate
r-stringr
r-testthat
)
optdepends=(
r-blob
r-cli
r-curl
r-dbi
r-dbplyr
r-decor
r-distro
r-dplyr
r-duckdb
r-hms
r-jsonlite
r-knitr
r-lubridate
r-pillar
r-pkgload
r-reticulate
r-rmarkdown
r-stringi
r-stringr
r-sys
r-testthat
r-tibble
r-tzdb
r-withr
)
source=("https://cran.r-project.org/src/contrib/${_pkgname}_${_pkgver}.tar.gz"
"fix-build.patch")
md5sums=('958ac3fdbdff912a7ed9757a62f6ba8f'
'905a328d53b0b7591f769e07c29c3937')
b2sums=('c58f313894fb4f1fd5145d198f0999bd49cc6707f4d2ad842c60ae3285eb5183cf0bb8662cf173350c70ee3e83da40a6bbdb0a19b71f35b507dae609fedd5cfa'
'6feffc1a3ff38014a9f644de778f0056f0f48787ce9a4d40bff8d27d8e42df2b05f258638150cadbd5b1a18d4697f35bf07cb8d9a78ba6357b8d94ef9d714874')
prepare() {
# fix build with system arrow, skip failing tests
patch -Np1 -i fix-build.patch
}
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname" \
--configure-vars=ARROW_R_ALLOW_CPP_VERSION_MISMATCH=true
}
_check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
}
|